Unterschiede

Hier werden die Unterschiede zwischen zwei Versionen angezeigt.

--- papierkorb:editor.blk [2025-08-16 17:50] – ↷ Seite von projects:editor.blk nach papierkorb:editor.blk verschoben mka
+++ papierkorb:editor.blk [Unbekanntes Datum] (aktuell) – gelöscht - Externe Bearbeitung (Unbekanntes Datum) 127.0.0.1
@@ Zeile 1: / Zeile 1: @@
-===Mode-less full feature text editor===
-<code>
-list Screen 0 not modified
-\ VEDIT  - FORTHSTAR  SCREEN EDITOR            22:23JWB11/11/85
-\ Last change:   Screen  068                   21:11JWB11/13/85
-Before loading the editor make the following changes to your
-UTILITY.BLK  Screen File.
-
-DEFER EDIT   ' LIST IS EDIT  \ Screen 6 Line 14 :  add this line
-
-    THEN  EDIT  ;   \ Screen 7 Line 15  replace LIST with EDIT
-
-ALSO !!   The recompiled system will overwrite the file
-           FORTH83.COM  on the disk in drive 1.
-
-   DO YOU HAVE A BACKUP  INCASE SOMETHING GOES WRONG!!
-
-   PRESS   C   TO CONTINUE THE LOAD  ANY OTHER TO ABORT!!
-
-list Screen 1 not modified
-\ EDITOR LOAD BLOCK                            22:27JWB11/11/85
-: ARE.YOU.SURE?  0 LIST  KEY ASCII C <> ABORT" LOAD CANCELED" ;
-   ARE.YOU.SURE?
-CR .( LOADING  VEDIT EDITOR AND REBUILDING  SYSTEM )
-ONLY FORTH DEFINITIONS ' NOOP IS WHERE
-  ' P!     >NAME    FENCE !  FORGET FUDGE  4 VIEW# !
-   FROM UTILITY.BLK   2 LOAD     CR .( UTL     LOADED )
-   FROM UTILITY.BLK  22 LOAD     CR .( SHADOW  LOADED ) CR
-    5 VIEWS   EDITOR.BLK  5 VIEW# !
-    4 124 THRU  CR .( EDITOR LOADED ) 4 VIEW# !
-   FROM UTILITY.BLK  28 LOAD     CR .( DUMPING LOADED)
-   FROM UTILITY.BLK  31 LOAD     CR .( SEEING  LOADED)
-   FROM UTILITY.BLK  43 LOAD     CR .( SHOWING LOADED)
-   FROM UTILITY.BLK  49 LOAD     CR .( BUGGING LOADED)
-   FROM UTILITY.BLK  52 LOAD     CR .( TASKING LOADED)
-   WARNING ON -->
-list Screen 2 not modified
-\ Load up the system                           18:51jwb11/05/85
-   5  VIEW# !
-: HELLO   (S -- )
-    CR ." 8086 Forth 83 Model"
-    CR ." Version 2.1.0     01Jun84"
-    CR ." Recompiled        08Nov87"
-    CR ." VEDIT by JW Brown 13Nov85" CR
-    START   ONLY FORTH ALSO DEFINITIONS   ;   ' HELLO IS BOOT
-
-: MARK    (S -- )
-    CREATE    DOES> (FORGET)  FORTH DEFINITIONS  ;
-MARK EMPTY     HERE FENCE !
-CR .( System has been loaded, Size = ) HERE U.
-( EXIT )  \ Remove brackets on EXIT when testing mods to EDITOR
-
-SAVE-SYSTEM FORTH83.COM CR .( System saved as FORTH83.COM )
-list Screen 4 not modified
-\ Define vocabularies, set up search order     23:16JWB11/04/85
-
-ONLY FORTH DEFINITIONS VOCABULARY EDITOR
-
-ONLY FORTH ALSO ROOT   DEFINITIONS
-
-: EDITOR EDITOR ;
-
-ONLY FORTH ALSO EDITOR ALSO DEFINITIONS  DECIMAL
-
-ORDER
-
-
-
-
-
-list Screen 5 not modified
-\ VIDEO-IO                                     23:15JWB11/04/85
-\ Call video-io BIOS routines with type $10=16 INTerupt.
-CODE VIDEO-IO  ( dx cx bx ax   dx' cx' bx' ax')
-         AX POP          \ Pop all registers.
-         BX POP
-         CX POP
-         DX POP
-         RP PUSH         \ Save return stack pointer = BP
-         16 INT          \ Call video io routines.
-         RP POP          \ Restore return stack pointer.
-         DX PUSH         \ Return all registers to user.
-         CX PUSH
-         BX PUSH
-           1PUSH         \ Push AX and fall into NEXT
-            END-CODE
-
-list Screen 6 not modified
-
-  VARIABLE $KBF
-\ Leave true flag if KBF has changed.  New value in $KBF .
-CODE KBF?  ( --  flag ) \ Was:  $KBF @ KBF DUP $KBF ! <>
-         2 # AH MOV      \ Function number 2 for kb flag
-             22 INT      \ Call KBF is returned in AL
-          AH AH SUB      \ Clear high byte of AX.
-      $KBF # DI MOV      \ Address of old KBF to DI
-     0 [DI]  BX MOV      \ Fetch old value of KBF
-          AX BX CMP      \ Compare new value with old.
-0= IF    AX AX SUB      \ Leave false flag if the same
-  ELSE AX 0 [DI] MOV     \ Update $KBF and
-        -1 # AX MOV      \ return true if KBF has changed.
-  THEN          1PUSH    \ Push AX and fall into NEXT
-                END-CODE
-
-list Screen 7 not modified
-\ INIT-WINDOW                                  23:28JWB11/04/85
-\ Scroll active page up.
-CODE INIT-WINDOW ( ulc ulr lrc lrr atrib   -- )
-           AX  POP   AL BH MOV   \ ulc=upper left column
-           AX  POP   AL DH MOV   \ ulr=upper left row
-           AX  POP   AL DL MOV   \ lrc=lower right column
-           AX  POP   AL CH MOV   \ lrr=lower right row
-           AX  POP               \ Attribute byte used.
-        AL CL  MOV               \ 07 is for normal text.
-    1536 # AX  MOV               \  1536 = 600 hex
-           RP  PUSH
-           16  INT
-           RP  POP
-           NEXT   END-CODE
-
-
-list Screen 8 not modified
-\ GOTOXY  AT {KEY}                             18:43jwb11/05/85
-\ Move cursor to new location at (col,row).
-CODE AT (S col row   -- )
-         AX POP          \ Get cursor row.
-         DX POP          \ Get cursor column.
-      AL DH MOV          \ Pack into DX for function call.
-      BH BH XOR          \ Set screen page number to zero.
-    2  # AH MOV          \ Function 2 is set cursor position.
-         16 INT          \ Call video io
-            NEXT         \ Next word please.
-            END-CODE
-: GOTOXY  AT ;
-\ Wait for key without checking break key!!
-: {KEY} (S --  char )
-          0 7  BDOS  255 AND  ;
-
-list Screen 9 not modified
-\ KBF  @DATE                                   18:43jwb11/05/85
-\ Return the current state of the keybord flag  KB_FLAG
-CODE KBF  ( --  kbf )
-         2 # AH MOV      \ Function number 2 for kb flag
-             22 INT      \ Call routine.
-          AH AH SUB      \ Clear high byte of AX.
-                1PUSH    \ Push AX and fall into NEXT
-                END-CODE
-\ Fetch date from DOS.  Returned in packed form, see (.DATE)
-CODE @DATE ( --  year mmdd )
-     42 ( 2A) # AH MOV
-     33 ( 21)      INT
-     CX            PUSH
-     DX            PUSH
-             NEXT  END-CODE
-
-list Screen 10 not modified
-\  @TIME  TSMH  TT SS MM HH                    18:49jwb11/05/85
-\ Fetch time from DOS.  Returned packed in TSMH .
-CREATE TSMH 4 ALLOT
-
-: TTT TSMH    C@ ;   : SSS TSMH 1+  C@ ;
-: MMM TSMH 2+ C@ ;   : HHH TSMH 3 + C@ ;
-
-CODE  @TIME ( --  -- )
-     44 ( 2C) # AH MOV
-     33 ( 21)      INT
-         TSMH # DI MOV
-        DX  0 [DI] MOV
-        CX  2 [DI] MOV
-             NEXT  END-CODE
-
-
-list Screen 11 not modified
-\ ATRIB VEMIT                                  20:18JWB11/07/85
-   VARIABLE  ATRIB    \ Current character attribute.
-
-\ Emit character according to current attribute in ATRIB
-CODE VEMIT   ( char   -- )
-        ATRIB # DI MOV     \ First output a space with
-         0 [DI] BX MOV     \ with the color attribute.
-         2336 # AX MOV     \ 0920HEX
-            1 # CX MOV     \ Number of spaces to output.
-                16 INT     \ Bios function call.
-                AX POP     \ Fetch character to output.
-           14 # AH MOV     \ Now output actual character
-                16 INT     \ this time cursor will advance
-        #OUT #  DI MOV     \ to the next legal position.
-            0 [DI] INC     \ Increment FORTH's character count.
-             NEXT    END-CODE
-list Screen 12 not modified
-\  (KEY?)                                      20:07   03/14/86
-
-
-\ Skan for key press returning true if key is down.
-CODE (KEY?)  ( --  flag )
-                  1 # AH MOV
-                      22 INT
-         0= IF    0 # AX MOV        \ FALSE if no key press.
-            ELSE -1 # AX MOV        \ TRUE  if key pressed.
-            THEN
-                        1PUSH  END-CODE
-
-
-
-
-
-list Screen 13 not modified
-\  CUR@    CUR!                                23:58JWB11/04/85
-CODE CUR@ ( --  rc )  \ Fetch cursor position as 16-bit word.
-         3 # AH MOV
-          BH BH SUB
-             16 INT
-             DX PUSH
-                NEXT
-                END-CODE
-\ Restore cursor position, row in hi byte col in low byte.
-CODE CUR! ( rc  -- )
-         2 # AH MOV
-          BH BH SUB
-             DX POP
-             16 INT
-                NEXT
-                END-CODE
-list Screen 14 not modified
-\  MATCH                                       14:12JWB06/16/85
-ASSEMBLER DEFINITIONS
-
-LABEL MATCH2   \ Leaves flag & byte advance
-         SI AX MOV       \ Current cursor address.
-            SI POP       \ Original cursor address.
-         SI AX SUB       \ Byte count to advance.
-         DI SI MOV       \ Restore interpretive pointer.
-  ( dx ax )   2PUSH      \ Flag, 0 no match, non zero match.
-                         \ Byte count to advance.
-
-LABEL MATCH1
-         CX POP CX POP CX POP CX POP
-         MATCH2 #) JMP
-EDITOR DEFINITIONS
-
-list Screen 15 not modified
-\ MATCH                                        14:12JWB06/16/85
-
-CODE    MATCH CLD       \ Set for auto increment.
-         SI DI MOV       \ Save interpretive pointer.
-            CX POP       \ String length.
-            BX POP       \ String address.
-            DX POP       \ Byte count to end of screen.
-            SI POP       \ Address of cursor on screen.
-            SI PUSH      \ Save copy of cursor address.
-BEGIN      AL LODS      \ Fetch byte from screen.
-     0 [BX] AL CMP       \ Compare with string.
-0= IF      DX PUSH      \ Possible match, save
-            BX PUSH      \ current position.
-            CX PUSH
-            SI PUSH
-
-list Screen 16 not modified
-\ MATCH                                        14:12JWB06/16/85
-
-BEGIN       CX DEC      \ Decrement string length.
-         MATCH1 JE      \ If zero we have a match.
-             DX DEC      \ Decrement bytes to end of screen.
-      MATCH1    JE       \ If zero we are at end of screen.
-             BX INC      \ Increment string address.
-             AL LODS     \ Get next byte from screen.
-      0 [BX] AL CMP      \ Compare with string byte.
-0<> UNTIL   SI POP      \ Restore pointers and counts.
-             CX POP
-             BX POP
-             DX POP
-THEN        DX DEC      \ Decrement byte to end of screen
-0= UNTIL    MATCH2 #) JMP
-         END-CODE
-list Screen 17 not modified
-\ (OF)                                         14:12JWB06/16/85
-\ EQUIVALENT TO   OVER = IF  DROP
-CODE (OF)
-            AX   POP    BX  POP
-        BX  AX   CMP
-      0<> IF BX  PUSH
-      0 [IP] IP  MOV
-                 NEXT
-      THEN   IP  INC
-             IP  INC
-                 NEXT END-CODE
-
-
-
-
-
-list Screen 18 not modified
-\ CASE OF ENDOF ENDCASE                        14:12JWB11/08/87
-( see FORTH DIMENSIONS, II/3 page 37 )
-
-: CASE          CSP @ !CSP TRUE ; IMMEDIATE
-
-: OF            ?CONDITION COMPILE (OF) ?>MARK ; IMMEDIATE
-
-: ENDOF         COMPILE BRANCH ?>MARK
-                 2SWAP  ?>RESOLVE TRUE  ; IMMEDIATE
-
-: ENDCASE       ?CONDITION  COMPILE DROP BEGIN SP@
-                 CSP @ = 0= WHILE ?>RESOLVE
-                           REPEAT CSP ! ; IMMEDIATE
-
-
-
-list Screen 19 not modified
-\ FIRSTF  NEXTF                                14:50   11/10/85
-\ Search for first match of file spec at adr.
-CODE FIRSTF ( adr   flag )
-            DX  POP      \ Offset of ASCIIZ file specification.
-          CX CX XOR      \ Set attribute to 0 for normal files.
-       78 #  AH MOV      \ Searh for first match.
-             33 INT
-U>= IF   AX AX XOR  THEN   \ Carry flag set if error.
-               1PUSH        \ Push AX containing the error code.
-            END-CODE
-\ Search for next file match.
-CODE NEXTF  ( --   flag )
-       79 #  AH MOV      \ Search for next match.
-             33 INT
-U>= IF   AX AX XOR  THEN      \ Carry set if error.
-               1PUSH END-CODE  \ Push error flag.
-list Screen 20 not modified
-\ DBUFF ADD*.*  ADD*.*?                        15:21JWB11/10/85
-  128 CONSTANT DBUFF
-\ Add *.* to file spec at adr.
-: ADD*.*  ( adr  adr )
-           DUP " *.*" ROT COUNT  +   SWAP CMOVE
-                  DUP C@ 3 + OVER C! ;
-\ Add *.* if null spec or drive spec only.
-: ADD*.*? ( adr  adr )
-          DUP C@ 0=                      \ Null spec?
-          IF   ADD*.*                    \ Add *.* if so.
-          ELSE DUP C@ 2 =                \ Maybe drive only.
-               IF DUP 2+ C@ ASCII : =    \ Is it drive spec?
-                    IF  ADD*.*           \ Add *.* if so.
-          THEN THEN THEN ;
-
-
-list Screen 21 not modified
-\ DISP-FNAME                                   15:35JWB11/10/85
-\ Display a filename and size from DOS scratch area at HERE
-: DISP-FNAME
-      #OUT @ IF 3 SPACES   THEN DBUFF 42 + DBUFF 30 +
-          DO   I  C@ ?DUP
-               IF    DUP BL >
-                     IF   DUP ASCII A >=
-                          OVER ASCII Z <= AND
-                          IF   32 OR THEN
-                     THEN VEMIT
-                     ELSE  LEAVE
-                THEN
-          LOOP    12 #OUT @ 20 MOD - SPACES
-          DBUFF 26 + DUP @ SWAP 2+ @ 6 D.R ;
-
-
-list Screen 22 not modified
-\ (DIR)                                        15:35JWB11/10/85
-\ Display directory based on file spec at adr.
-: (DIR)  ( adr   -- )
-    ADD*.*?  DBUFF
-    26 BDOS DROP           \ Set data transfer area  scratch pad.
-    DUP DUP C@ + 1+ 0 SWAP C!
-    1+  FIRSTF 0=                  \ Any match?
-       IF 6 3 AT     6 3  #OUT OFF
-           BEGIN  DISP-FNAME  #OUT @ 50 >
-           IF  1+ 2DUP AT     #OUT OFF THEN  \ More files?
-           NEXTF  UNTIL 2DROP
-   THEN  ;
-
-
-
-
-list Screen 23 not modified
-\ 3DROP FUNCTION-KEYS                          14:13JWB06/16/85
-: 3DROP  DROP 2DROP ;
-
-     27 CONSTANT ESC
-     13 CONSTANT RETURN
-     10 CONSTANT LF
-     82 CONSTANT INS
-     59 CONSTANT F1
-     83 CONSTANT DEL
-     60 CONSTANT F2
-     15 CONSTANT BACK-TAB
-     61 CONSTANT F3
-     75 CONSTANT LEFT-ARROW
-
-
-
-list Screen 24 not modified
-\ VIDEO MODES                                  20:37JWB11/06/85
-    2 BASE !
-: -BLINK     ATRIB  @ 01111111 AND ATRIB ! ;
-: BLINK      ATRIB  @ 10000000  OR ATRIB ! ;
-   DECIMAL
-\ Type n bytes of string at adr using current atribute byte.
-: VTYPE  ( adr  n   -- )
-          0 ?DO COUNT VEMIT LOOP DROP ;
-
-\ Set cursor type.  Start line = sl  End line = el
-\ Function 1 of type $10 int.
-: SET-CURSOR  ( sl el    -- )
-       SWAP FLIP + 0 SWAP 0 256
-       VIDEO-IO 2DROP 2DROP ;
-
-
-list Screen 25 not modified
-\  BIG  LITTLE AND NO  CURSORS                 20:39JWB11/06/85
-\ Make a big cursor.
-: BIG-CURSOR ( --  -- )
-         0 6 SET-CURSOR  ;
-\ Make a little cursor.
-: LITTLE-CURSOR ( --  -- )
-         6 7 SET-CURSOR  ;
-\ Make no cursor.
-: NO-CURSOR ( --  -- )
-         8 8 SET-CURSOR ;
-: -NO-CURSOR ( --  -- )
-              0 8 SET-CURSOR ;
-: SELECT-CURSOR ( --  -- )
-         KBF  128 AND
-         IF BIG-CURSOR
-         ELSE LITTLE-CURSOR THEN  ;
-list Screen 26 not modified
-\ CHK .INS .CAP .NUM .SRL .STAMP               22:57jwb11/06/85
-  VARIABLE $INS  5 , ," INS"   VARIABLE $NUM 10 , ," NUM"
-  VARIABLE $CAP 15 , ," CAP"   VARIABLE $SRL 20 , ," SRL"
-  VARIABLE $AUTO     $AUTO OFF
-: CHK \ nf ofaddr
-     2DUP  @ =  OVER  2+ @ CUR!
-     IF   4 + COUNT VTYPE   DROP
-     ELSE 2DROP 3 SPACES THEN  ;
-: .STAMP ( --  -- ) CUR@ 25 CUR!  $AUTO @
-     IF           ." STAMP"            ELSE ."      " THEN CUR! ;
-  HEX : .INS  ( kbf  -- ) 80 AND $INS CHK ;
-      : .CAP  ( kbf  -- ) 40 AND $CAP CHK ;
-      : .NUM  ( kbf  -- ) 20 AND $NUM CHK ;
-      : .SRL  ( kbf  -- ) 10 AND $SRL CHK ;
-      : $INIT 80 $INS ! 40 $CAP ! 20 $NUM ! 10 $SRL ! ; DECIMAL
-
-list Screen 27 not modified
-\ FUNCTION KEYS                                14:13JWB06/16/85
-     62 CONSTANT F4
-     77 CONSTANT RIGHT-ARROW
-     63 CONSTANT F5
-     72 CONSTANT UP-ARROW
-     64 CONSTANT F6
-     80 CONSTANT DOWN-ARROW
-     65 CONSTANT F7
-     71 CONSTANT HOME
-     66 CONSTANT F8
-     79 CONSTANT END
-     67 CONSTANT F9
-     73 CONSTANT PG-UP
-     68 CONSTANT F10
-     81 CONSTANT PG-DN
-    115 CONSTANT ^LEFT-ARROW
-list Screen 28 not modified
-\ FUNCTION KEYS                                14:13JWB06/16/85
-     94 CONSTANT ^F1
-    116 CONSTANT ^RIGHT-ARROW
-     95 CONSTANT ^F2
-     96 CONSTANT ^F3
-     97 CONSTANT ^F4
-    119 CONSTANT ^HOME
-     98 CONSTANT ^F5
-    117 CONSTANT ^END
-     99 CONSTANT ^F6
-    132 CONSTANT ^PG-UP
-    100 CONSTANT ^F7
-    118 CONSTANT ^PG-DN
-
-
-
-list Screen 29 not modified
-\  FUNCTION KEYS                               08:31JWB06/22/85
-    101 CONSTANT ^F8
-    102 CONSTANT ^F9     48 CONSTANT ALTB
-    103 CONSTANT ^F10    50 CONSTANT ALTM
-    104 CONSTANT ALTF1   46 CONSTANT ALTC
-     22 CONSTANT ALTU    31 CONSTANT ALTS
-    105 CONSTANT ALTF2   30 CONSTANT ALTA
-     49 CONSTANT ALTN    34 CONSTANT ALTG
-    106 CONSTANT ALTF3   24 CONSTANT ALTO
-    107 CONSTANT ALTF4   32 CONSTANT ALTD
-    108 CONSTANT ALTF5   23 CONSTANT ALTI
-    109 CONSTANT ALTF6   20 CONSTANT ALTT
-    110 CONSTANT ALTF7
-    111 CONSTANT ALTF8
-    112 CONSTANT ALTF9
-    113 CONSTANT ALTF10
-list Screen 30 not modified
-\ VARIABLES                                    09:15JWB06/20/85
-   VARIABLE     $SCRATCH
-: HELD         $SCRATCH  @  +  ;
-: SCREEN       $SCRATCH  @  1024 +  +  ;
-: BACKBUF      $SCRATCH  @  2048 +  +  ;
-: SEARCHBUF    $SCRATCH  @  3072 +  +  ;
-: REPLACEBUF   $SCRATCH  @  3136 +  +  ;
-: INSBUF       $SCRATCH  @  3392 +  +  ;
-   VARIABLE CURSOR
-   VARIABLE SCREEN#
-   VARIABLE $INSERT
-   VARIABLE TAB#
-   VARIABLE HOLD-DEPTH
-   VARIABLE <MATCH>
-   VARIABLE $TITLE       63 ALLOT
-   VARIABLE $SECONDS
-list Screen 31 not modified
-\ $REPLACE PREV-FILE $DIRECTORY                14:13JWB06/16/85
-   VARIABLE $INITIALS     3 ALLOT
-   VARIABLE $REPLACE
-   VARIABLE PREV-FILE   B/FCB ( 42 ) ALLOT
-   VARIABLE CUR-FILE    B/FCB        ALLOT
-   VARIABLE OLD-FILE
-   VARIABLE $DIRECTORY
-   VARIABLE BROWSING
-\ Open a new screen file give address of counted string.
-: OPEN-SCR   \  addr  ---
-         COUNT CUR-FILE [ DOS ] (!FCB) [ EDITOR ]
-         CUR-FILE [ DOS ] !FILES
-         IN-FILE @ DUP 15 BDOS  DOS-ERR?  TUCK NOT
-         IF   DUP FILE-SIZE 1- SWAP MAXREC# !
-         THEN  [ EDITOR ] ;
-
-list Screen 32 not modified
-\ SPLIT .DATE TIME@ (.TIME) .TIME              18:46jwb11/05/85
-: SPLIT ( hilo   hi lo )
-         256 /MOD SWAP ;
-
-: (.DATE)  ( --   addr count )
-       @DATE  SWAP  1900 -
-        0  <#  #  #  2DROP ASCII / HOLD  SPLIT
-             0 #  #  ASCII / HOLD  2DROP  0 #  #  #>  ;
-
-
-
-
-
-
-
-
-list Screen 33 not modified
-\  .TIME  .DATE                                18:48jwb11/05/85
-
-\ Format the time ready for typing.
-: (.TIME) ( --  adr count )
-      @TIME
-     SSS  0 <# # # ASCII : HOLD 2DROP
-     MMM  0    # # ASCII : HOLD 2DROP
-     HHH  0    # # #> ;
-
-
-
-: .TIME (.TIME) VTYPE ;
-
-: .DATE (.DATE) VTYPE ;
-
-
-list Screen 34 not modified
-\ CLOCK   PCKEY <KEY>                           22:04   11/12/85
-: SS+5 5 $SECONDS +! ;
-: .CLOCK ( --  -- )
-         @TIME SSS   $SECONDS @  2DUP 60 = SWAP 5 < AND
-         IF $SECONDS OFF THEN  >=
-         IF  NO-CURSOR 32 CUR!   .TIME
-                     SELECT-CURSOR SS+5 THEN ;
-: PCKEY ( --  char|code 0 )
-         BEGIN (KEY?) NOT
-         WHILE  CUR@ KBF?
-         IF    NO-CURSOR  KBF DUP
-              .INS  DUP .NUM  DUP
-              .CAP  .SRL SELECT-CURSOR
-         THEN    .CLOCK   CUR!
-         REPEAT  {KEY}  DUP
-          0= IF {KEY} SWAP THEN ;
-list Screen 35 not modified
-\ MODE  .STATE  #IN                            22:55jwb11/06/85
-: <KEY> ( --  n )
-         BEGIN PCKEY DUP 0= WHILE BEEP 2DROP REPEAT ;
-: .STATE CUR@ KBF
-          DUP .INS DUP .CAP DUP .NUM .SRL  .STAMP
-                      SELECT-CURSOR CUR! ;
-
-: #IN  ( --- n )
-   0 BEGIN
-   KEY
-   DUP 13 =  IF DROP EXIT THEN
-   DUP 8 =   IF VEMIT 32 VEMIT 8 VEMIT 10 / ELSE
-                DUP 48 < OVER 57 > OR IF DROP 7 VEMIT
-                ELSE DUP VEMIT 48 - SWAP 10 * + THEN THEN
-   AGAIN ;
-
-list Screen 36 not modified
-\ CLEARSCREEN  SW -SW                          18:17JWB11/09/85
-\ Clear entire screen.
-: CLEARSCREEN   ( --  -- )
-        0  0  79 24 ATRIB @ INIT-WINDOW  0  0  AT      ;
-
-\ Swap in our vectors for EMIT AND KEY .
-: SW   ( --  -- )
-       ['] VEMIT IS EMIT
-       ['] <KEY>  IS KEY  ;
-
-\ Restore original routines for EMIT AND KEY .
-: -SW  ( --  -- )
-       ['] (EMIT) IS EMIT
-       ['] (KEY)  IS KEY  ;
-
-
-list Screen 37 not modified
-\  STAMP-PAD                                   23:09JWB06/23/85
-
-\ Set up screen title as comment with time date and initials.
-: STAMP-PAD ( --  -- )
-               $TITLE  42 +  22 BLANK
-      ( $205C or "\ " )  8284  $TITLE !
-    (.DATE)     $TITLE  55 +  SWAP  CMOVE
-    (.TIME) 3 - $TITLE  47 +  SWAP  CMOVE
-    $INITIALS  COUNT $TITLE  52 +  SWAP  CMOVE  ;
-
-
-
-
-
-
-
-list Screen 38 not modified
-\ DATE-SCREEN                                  23:14JWB06/23/85
-
-
-\ Stamp current screen with time, initials and date.
-: DATE-SCREEN  ( --  -- )
-        0  SCREEN  $TITLE  42 CMOVE  STAMP-PAD
-        $TITLE  0  SCREEN  C/L CMOVE  ;
-
-
-
-
-
-
-
-
-
-list Screen 39 not modified
-\ DATE-SCR0                                    23:13JWB06/23/85
-\ Stamp second line of screen 0 with date and last screen
-\ modified.
-: DATE-SCR0  ( --  -- )
-    $TITLE  C/L BLANK
-    " Last change:   Screen "  $TITLE  2+  SWAP  CMOVE
-     0  <#  #  #  #  #>  $TITLE  25 +  SWAP  CMOVE
-    STAMP-PAD  $TITLE  0  BLOCK C/L + C/L CMOVE  UPDATE  ;
-
-
-
-
-
-
-
-
-list Screen 40 not modified
-\ CURSOR-CHK @(CURSOR)                         16:28JWB06/22/85
-\ Store top of stack as current cursor value
-: CURSOR!  ( n  -- )
-         CURSOR ! ;
-\ Fetch current value of cursor.
-: CURSOR@  ( --  n )
-         CURSOR @  ;
-\ Check for out of bounds cursor.
-: CURSOR-CHK    ( --  -- )
-         CURSOR@  1024 + 1024 MOD CURSOR! ;
-\ Fetch storrage address corresponding to current cursor.
-: ADCUR   ( --  adr )
-       CURSOR@ SCREEN  ;
-\ Fetch character stored at current cursor location.
-: @(CURSOR)  ( --  char )
-         ADCUR   C@  ;
-list Screen 41 not modified
-\ !(CURSOR  .CURSOR   CHAR-TO-EOL              20:49JWB11/06/85
-\ Store character at current cursor position.
-: !(CURSOR)  ( char  -- )
-        ADCUR  C!  ;
-
-\ Print current cursor position.
-: .CURSOR  ( --  -- )
-        CURSOR@  C/L /MOD  2DUP  SWAP  NO-CURSOR
-        50 1 AT     0 <# # # BL HOLD 2DROP 0 # # #> VTYPE
-        6 3 D+ AT     SELECT-CURSOR ;
-
-\ Return character count to end of current line.
-: CHAR-TO-EOL  ( --  n )
-         C/L CURSOR@ OVER MOD - ;
-
-
-list Screen 42 not modified
-\ +.CURSOR .LINE ?LINE                         20:49JWB11/06/85
-\ Add n to current current cursor and print it.
-: +.CURSOR  ( n  -- )
-        CURSOR  +!  CURSOR-CHK  .CURSOR  ;
-
-\ Print line n of the current screen.
-: .LINE   ( n  -- )
-         DUP  3  +  6 SWAP  AT
-         C/L *  SCREEN C/L VTYPE ;
-
-\ Return number of line that cursor is currently on.
-: ?LINE   ( --  n )
-         CURSOR@ C/L /  ;
-\ Leave true flag if there is a blank at the end of the line.
-: BLANK-AT-END?  ( --  flag )
-         ?LINE 1+ C/L * 1- SCREEN C@ BL = ;
-list Screen 43 not modified
-\ ?LINE64* .LINE-TO-END MOVE-LINE              08:46JWB06/22/85
-
-\ Return currsor position of start of line containing cursor.
-: ?LINE64*   ( --  n )
-         ?LINE C/L *  ;
-
-\  Reprint the line the cursor is currently on.
-: .LINE-TO-END   ( --  -- )
-         ?LINE  .LINE  ;
-
-\ Move line n1  to line n2 .
-: MOVE-LINE   ( n1 n2  -- )
-        SWAP C/L *  SCREEN  SWAP C/L *  SCREEN
-        C/L CMOVE  ;
-
-
-Screen 44 not modified
-\ MOVE-HOLD SCROLLDOWN  .CLEAN                 18:29JWB11/09/85
-\
-: MOVE-HOLD  ( n1  n2    -- )
-               SWAP C/L *  HELD
-               SWAP C/L *  HELD C/L CMOVE ;
-\ Scroll screen down one line.
-: SCROLLDOWN  ( x y x' y'  -- )
-    FLIP  +  -ROT   FLIP  + ATRIB @ FLIP 1793  \ $701=1793
-    VIDEO-IO  2DROP  2DROP  ;
-
-\ Wipe  reading or writing off upper right corner.
-: .CLEAN  ( --  -- )
-      NO-CURSOR CUR@ 56 1 AT
-       ."   F1 = HELP   "
-      CUR!  SELECT-CURSOR ;
-
-Screen 45 not modified
-\ SCROLLUP .SCREEN#                            20:42JWB11/07/85
-\ Scroll screen up one line.
-: SCROLLUP ( x y x' y'  -- )
-    FLIP   + -ROT   FLIP  +
-    ATRIB @ FLIP 1537 ( $601=1537 )
-    VIDEO-IO  2DROP  2DROP  ;
-
-
-\ Print screen number and current editing file.
-: .SCREEN#  ( --  -- )
-        .STATE    6 1  AT
-        ." Screen # " SCREEN#  @  .  SPACE
-        19 1  AT   BROWSING @
-        IF ." Browsing" ELSE ."  Editing" THEN
-        ."  file: " FILE? ;
-
-Screen 46 not modified
-\ .WRITING  .READING                           14:18JWB06/23/85
-
-
-: .WRITING  ( --  -- )
-      NO-CURSOR CUR@  56 1  AT
-                BLINK  ."   Writing disk" -BLINK
-      CUR! SELECT-CURSOR ;
-: .READING  ( --  -- )
-      NO-CURSOR CUR@ 56 1 AT
-                BLINK  ."   Reading disk" -BLINK
-      CUR! SELECT-CURSOR ;
-
-
-
-
-
-Screen 47 not modified
-\ PRINT-SCREEN                                 20:49JWB11/06/85
-\ Send current screen to the printer.
-: PRINT-SCREEN ( --  -- )
-         -SW  PRINTING ON CR
-          SCREEN# @  7 SPACES
-         ." Screen#" 4 .R 3 SPACES FILE?
-          3 SPACES  .DATE SPACE .TIME
-         16 0 DO  CR   I 6 .R  SPACE
-              0 SCREEN I C/L * + C/L -TRAILING TYPE
-              LOOP
-         CR  PRINTING OFF SW  ;
-
-
-
-
-
-Screen 48 not modified
-\ PUSH-TO-PROCEED @(SCREEN#) CLEAR-PROMPT      19:56JWB11/11/85
-
-\ Prompt for key press to continue.
-: PUSH-TO-PROCEED  ( --  -- )
-       ." Press any key to continue. " KEY  DROP ;
-
-
-\ Fetch screen n to the editing & backup buffer areas.
-: @(SCREEN#)  ( n  -- )
-       .READING  SCREEN#  @  BLOCK  0  SCREEN
-       1024 CMOVE  0  SCREEN  0  BACKBUF  1024 CMOVE  ;
-
-
-\ Clear n lines of prompt area below screen.
-: CLEAR-PROMPT  ( n  -- )   1 MAX 5 MIN 19 +
-        0  20 ROT 79 SWAP  ATRIB @ INIT-WINDOW 6 20 AT     ;
-Screen 49 not modified
-\ !(SCREEN#                                    08:53JWB06/22/85
-\ Store current screen in a FORTH buffer and mark as updated.
-: !(SCREEN#)  ( --  -- )
-    .WRITING  SCREEN#  @
-    BLOCK  0  SCREEN  SWAP
-    2DUP  1024 COMP 0=
-      IF 2DROP
-      ELSE $AUTO  @
-         IF DATE-SCREEN
-         THEN 1024 CMOVE  UPDATE  $AUTO  @
-         IF SCREEN#  @  DATE-SCR0
-         THEN
-      THEN ;
-
-
-
-Screen 50 not modified
-\ #RECORDS DISPLACEMENT ?SCREENS CHECK-SCR     21:01JWB11/13/85
-\ Return n, the maximum number of records in current file.
-: #RECORDS ( --  n )
-        FILE @ [ DOS ] MAXREC# [ EDITOR ] @ 1+ ;
-
-\ Return offset n, to the alternate or shadow screen.
-: DISPLACEMENT  ( --  n )
-        #RECORDS 0 16 UM/MOD NIP ;
-
-\ Return the number n, of the last screen in current file.
-: ?SCREENS  ( --  n )
-        #RECORDS 0 8 UM/MOD NIP 1- ;
-
-\ Do not allow n to exceed the last available screen.
-: CHECK-SCREEN  ( n    n')
-         0 MAX       ?SCREENS  MIN  ;
-Screen 51 not modified
-\  SHADOW-SCR IBUF IMOV                        19:58JWB11/11/85
-\ Convert screen n to corresponding shadow s.
-: SHADOW-SCR ( n   s )
-         DISPLACEMENT 2DUP < IF + ELSE - THEN ;
-   VARIABLE IPTR
-: IBUF ( --  adr )    \ Leave pointer into insert buffer.
-         0 INSBUF IPTR @  256 MOD + ;
-: IMOV ( --  -- )     \ Move character under cursor to ins buf.
-         $KBF @ 16 AND  \ Is scroll lock down?
-         IF   IPTR @ 256 <
-              IF   @(CURSOR) IBUF C! 1 IPTR +!
-              ELSE 2 CLEAR-PROMPT ." Insert buffer full!" CR
-                   BEEP PUSH-TO-PROCEED .CURSOR
-              THEN
-         THEN ;
-
-Screen 52 not modified
-\ IBLANK  BORDER                               20:05JWB11/11/85
-: IBLANK ( --  -- )   \ Clear insert buffer to blanks.
-         IPTR OFF IBUF 256 BLANK ;
-\ Display screen border and exit prompt.
-: BORDER  ( --  -- )
-    CLEARSCREEN  PAD  64 196 FILL  5 2  AT
-    218 VEMIT  PAD  64 VTYPE
-    191 VEMIT  5 19 AT      192 VEMIT
-    PAD  64 VTYPE  217 VEMIT  16 0
-      DO 5 I  3  +  AT      179 VEMIT
-        70 I  3  +  AT      179 VEMIT
-      LOOP     72  5 AT ."  PRESS"
-               72  7 AT ."   Esc "
-               72  9 AT ."   TO"
-               72 11 AT ."  EXIT"
-               72 13 AT ." EDITOR"  ;
-Screen 53 not modified
-\ SCAN+<>  SCAN+=                              09:28JWB06/22/85
-: SCAN+<>  ( char to.adr from.adr   count )
-         2DUP =                  \ Return 0 if there is
-         IF  3DROP 0             \ nothing to search.
-         ELSE 0 ROT ROT          \ Otherwise scan memory
-           DO OVER I C@ <>       \ from low to high until
-              ?LEAVE 1+          \ a missmatch is found.
-           LOOP NIP THEN ;       \ Return with count to mismatch.
-
-: SCAN+=   ( char to.adr from.adr   count )
-         2DUP =                  \ Return 0 if there is nothing
-         IF  3DROP 0             \ to search.
-         ELSE 0 ROT ROT          \ Other wise scan memory from
-           DO OVER I C@ =        \ low to high until
-              ?LEAVE 1+          \ a match is found.
-           LOOP NIP THEN ;       \ Return with count to match.
-Screen 54 not modified
-\                                              09:00JWB06/22/85
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-Screen 55 not modified
-\ .BLANK-SCREEN .SCREEN                        20:07JWB11/11/85
-\ Clear interior of screen window to blanks.
-: .BLANK-SCREEN ( --  -- )
-     6 3  69 18 ATRIB @ INIT-WINDOW  ;
-\ Display screen contents and headings.
-: .SCREEN  ( --   -- )
-    42 0  AT     .DATE
-    52 0  AT      ."  FORTHSTAR 2.1 "
-             .SCREEN#   .BLANK-SCREEN  16 0
-      DO I C/L *  SCREEN C/L -TRAILING  DUP
-         IF 6 I  3  +  AT      VTYPE
-         ELSE 2DROP
-         THEN
-      LOOP .CLEAN  .CURSOR  ;
-
-
-Screen 56 not modified
-\ NEW-SCREEN .SCREEN-TO-END CLEAR-PROMPT       20:50JWB11/06/85
-\ Display a new screen.
-: NEW-SCREEN ( --   -- )
-                @(SCREEN#)   CURSOR  OFF  .SCREEN  ;
-
-\ Redisplay lines from cursor to the end of the screen.
-: .SCREEN-TO-END ( --  -- )
-    6 ?LINE  3  +  69 18 ATRIB @ INIT-WINDOW
-    16 ?LINE
-      DO I C/L *  SCREEN C/L -TRAILING  DUP
-         IF 6 I  3  +  AT      VTYPE
-         ELSE 2DROP
-         THEN
-      LOOP .CURSOR  ;
-
-
-Screen 57 not modified
-\ .HOLD  WAIT.DIGIT                            18:36JWB11/09/85
-\ Display the top of the line stack.
-: .HOLD ( --  -- )
-      HOLD-DEPTH  @
-      IF 0 24 79 24 ATRIB @  INIT-WINDOW
-       0 24 AT     HOLD-DEPTH @ 3 .R SPACE
-       0 HELD 64 -TRAILING  VTYPE
-      ELSE 0  24 79 24 ATRIB @ INIT-WINDOW
-      THEN ;
-\ Wait n seconds for key press and convert to digit 1 ... 9
-: WAIT.DIGIT \ n   1 ...9
-         0 SWAP 2000 * 0
-         ?DO (KEY?)
-             IF DROP PCKEY DUP 0= IF 2DROP 0 THEN LEAVE THEN
-         LOOP
-         48 - 1 MAX 9 MIN  ;
-Screen 58 not modified
-\ NEXT-SCREEN PREV-SCREEN +MOVE                14:16JWB06/16/85
-\ Go to screen n.
-: GO-SCR  ( n   -- )
-         CURSOR@ >R !(SCREEN#) CHECK-SCREEN
-         SCREEN# ! NEW-SCREEN  R> CURSOR! ;
-\ Go to next screen.
-: NEXT-SCREEN ( --  -- )
-     SCREEN# @ ( 2 WAIT.DIGIT +) 1+ GO-SCR .CURSOR ;
-\ Go to previous screen.
-: PREV-SCREEN ( --  -- )
-     SCREEN#  @ ( 2 WAIT.DIGIT -) 1- GO-SCR .CURSOR ;
-\ Move lines from cursor to end up one ( down on screen).
-: +MOVE   ( --  -- )
-      ?LINE  15 <
-      IF ?LINE  1+  15
-         DO I  1-  I  MOVE-LINE  -1  +LOOP THEN ;
-Screen 59 not modified
-\ -MOVE  ASK-SCR  FIRST-SCR LAST-SCR           09:22JWB06/22/85
-\ Move lines from cursor to bottom down one ( up on screen).
-: -MOVE  ( --  --  )
-      ?LINE  15 -
-      IF 15 ?LINE
-         DO I  1+  I  MOVE-LINE     LOOP
-      THEN ;
-\ Prompt for input of new screen number.
-: ASK-SCR  ( --  n )
-         ." Enter screen number : "   #IN  ;
-\ Move to first screen of this file.
-: FIRST-SCR ( --  -- )
-             0 GO-SCR .CURSOR ;
-\ Move to the last screen of this file.
-: LAST-SCR  ( --  -- )
-             ?SCREENS GO-SCR .CURSOR ;
-Screen 60 not modified
-\ GO-SHADOW   PUSH-LINE   POP-LINE             20:14JWB11/11/85
-\ Toggle between current screen and its shadow screen.
-: GO-SHADOW ( --  -- )
-         SCREEN# @ SHADOW-SCR GO-SCR .CURSOR ;
-\ Push current line to line stack and display it.
-: PUSH-LINE ( --  -- )
-     -1  14 DO I  DUP  1+  MOVE-HOLD  -1 +LOOP
-      ?LINE64*  SCREEN  0  HELD C/L CMOVE  HOLD-DEPTH
-      @  1+  16 MIN  HOLD-DEPTH  !  .HOLD  .CURSOR  ;
-\ Pop line from line stack.
-: POP-LINE ( -- -- )
-     0  HELD  ?LINE64*  SCREEN C/L CMOVE  ?LINE
-    .LINE C/L HELD  0  HELD  960 CMOVE  960 HELD C/L BLANK
-    HOLD-DEPTH  @  1-  0  MAX  HOLD-DEPTH  !  .HOLD  .CURSOR ;
-
-
-Screen 61 not modified
-\ SPLIT-LINE SPREAD-LINE                       20:17JWB11/11/85
-\ Split line at current currsor position.
-: SPLIT-LINE ( --  -- )
-    +MOVE  ADCUR           C/L BLANK
-    .SCREEN-TO-END  ;
-\ Insert blank line at current curssor postion.
-: SPREAD-LINE ( --  -- )
-      ?LINE  15 -  DUP
-      IF ?LINE  1  -  14
-         DO I  DUP  1  +  MOVE-LINE  -1
-         +LOOP
-      THEN ?LINE64*  SCREEN C/L BLANK
-      IF 6 ?LINE  3  +  69 18 SCROLLDOWN
-      ELSE 15 .LINE  .CURSOR
-      THEN ;
-
-Screen 62 not modified
-\ DELETE-LINE                                  20:17JWB11/11/85
-\ Delete line at current currsor position and move rest up.
-: DELETE-LINE ( --  -- )
-      ?LINE  15 -  DUP
-      IF   ?LINE  1  + C/L *  SCREEN
-           DUP C/L -  OVER  1024
-           SCREEN  SWAP  -  CMOVE
-      THEN 15 C/L *  SCREEN C/L BLANK
-      IF 6 ?LINE  3  +  69 18 SCROLLUP
-      ELSE 15 .LINE  .CURSOR
-      THEN ;
-
-
-
-
-
-Screen 63 not modified
-\ FORWARD BACKUP PUT-CHAR TAB-RIGHT            20:20JWB11/11/85
-\ Move cursor forward one position.
-: FORWARD ( --  -- )
-         1 +.CURSOR  ;
-\ Back cursor up one position.
-: BACKUP  ( --  -- )
-        -1  +.CURSOR  ;
-\ Store character and display it.
-: PUT-CHAR ( char  -- )
-      DUP VEMIT !(CURSOR) FORWARD  ;
-\ Mover right to the next tab stop.
-: TAB-RIGHT ( --  -- )
-    TAB#  @  CURSOR@  C/L MOD
-    OVER  /  OVER  *  ?LINE64* +  +
-    CURSOR!  CURSOR-CHK  .CURSOR  ;
-
-Screen 64 not modified
-\ TAB-LEFT TAB-UP +TRANSPOSE                   20:22JWB11/11/85
-\ Move to the next tabstop on the left.
-: TAB-LEFT ( --  -- )
-    TAB#  @  CURSOR@  C/L MOD
-    OVER  /  OVER  *  ?LINE64* + SWAP  -
-    CURSOR!  CURSOR-CHK  .CURSOR  ;
-\ Move cursor up one position.
-: TAB-UP  ( --  -- )
-            -64 +.CURSOR  ;
-\ Transpose character under cursor with the one in front of it.
-: +TRANSPOSE ( --  -- )
-         CURSOR@ 1024 <
-         IF  ADCUR           @ 256 /MOD
-             PUT-CHAR
-             PUT-CHAR  BACKUP
-         THEN ;
-Screen 65 not modified
-\ TAB-DOWN ERASE-SCREEN  -TRANSPOSE            20:24JWB11/11/85
-
-\ Move cursor down one position.
-: TAB-DOWN  ( --   -- )
-             C/L +.CURSOR  ;
-
-\ Erase current screen to blanks.
-: ERASE-SCREEN  ( --  -- )
-    0 SCREEN  1024 BLANK  .BLANK-SCREEN
-    CURSOR  OFF .SCREEN#   .CURSOR  ;
-
-\ Transpose character under cursor with the one behind it.
-: -TRANSPOSE ( --  -- )
-         CURSOR@
-         IF  BACKUP  +TRANSPOSE BACKUP  THEN ;
-
-Screen 66 not modified
-\ ERASE-TO-END ERASE-LINE                      21:04JWB11/13/85
-
-\ Erase from cursor to end of screen with blanks.
-: ERASE-TO-END ( --  -- )
-    ADCUR  1024 CURSOR@ -
-    BLANK  .SCREEN-TO-END  ;
-
-\ Erase line that the cursor is on with blanks.
-: ERASE-LINE  ( --  -- )
-     ?LINE64* DUP CURSOR!
-     SCREEN C/L  BLANK .LINE-TO-END  .CURSOR  ;
-
-
-
-
-
-Screen 67 not modified
-\ ERASE-EOL (DELC) DELETE-CHAR                 21:04JWB11/13/85
-\ Erase line from cursor to end with blanks.
-: ERASE-EOL  ( --  -- )
-       ADCUR  CHAR-TO-EOL
-       2DUP BLANK  VTYPE  .CURSOR  ;
-\ Delete character under cursor.  Display not refreshed.
-: (DELC) ( --  -- )
-      IMOV CHAR-TO-EOL ADCUR
-      2DUP  DUP 1+ SWAP ROT CMOVE
-      + 1- BL SWAP C!  ;
-\ Delete character under cursor and refresh display.
-: DELETE-CHAR  ( --  -- )
-         (DELC)
-         ADCUR  CHAR-TO-EOL
-         -TRAILING 1+ VTYPE .CURSOR ;
-
-Screen 68 not modified
-\ (INS-CHAR)   SPREAD-CHAR  INSERT-CHAR        21:11JWB11/13/85
-\ Insert char at cursor position and advance cursor n positions.
-: (INS-CHAR) ( char n  -- )
-         SWAP                            \ c n
-         ADCUR  CHAR-TO-EOL              \ n c a e
-         2DUP + 1- C@ BL =               \ n c a e flag
-         IF 2DUP SWAP DUP 1+             \
-            ROT 1- CMOVE>
-            ROT 2 PICK C!
-            -TRAILING VTYPE  +.CURSOR
-         ELSE  2DROP 2DROP BEEP THEN ;
-\ Insert a blank at cursor position but do not advance cursor.
-: SPREAD-CHAR    ( --  --  )  BL 0 (INS-CHAR) ;
-\ Insert char at cursor postion and advance one position.
-: INSERT-CHAR    ( char  -- )    1 (INS-CHAR) ;
-
-Screen 69 not modified
-\ DELETE-CHARLFT NOT-EMPTY-LINE?               21:05JWB11/13/85
-
-\ Delete character behind cursor.
-: DELETE-CHARLFT ( --  -- )
-      CURSOR@ C/L MOD  0=
-      IF BEEP
-      ELSE -1  CURSOR  +!  .CURSOR  DELETE-CHAR
-      THEN ;
-
-\ Leave true flag if rest of line is not blank.
-: NOT-EMPTY-LINE? ( --  flag )
-      ADCUR  CHAR-TO-EOL
-      -TRAILING NIP 0<> ;
-
-
-
-Screen 70 not modified
-\ IGET   BACKSPACE                             20:28JWB11/11/85
-
-\ Insert character from ins buf at current cursor position.
-: IGET ( --  -- )
-     IPTR @  0<> BLANK-AT-END?  AND
-     IF   -1 IPTR +! IBUF C@ 0 (INS-CHAR)
-     ELSE BEEP THEN ;
-
-\ Backup and erase character behind cursor.
-: BACKSPACE ( --  -- )
-      CURSOR@ C/L MOD  0=
-      IF BEEP
-      ELSE -1 +.CURSOR BL !(CURSOR)
-            BL  VEMIT  .CURSOR
-      THEN ;
-
-Screen 71 not modified
-\ CURSOR-RIGHTWORD                             20:29JWB11/11/85
-\ Move cursor right one word.  Word traversed goes to the
-\ insert buffer if scroll lock is on.
-: CURSOR-RIGHTWORD ( --  -- )
-      BEGIN CURSOR@  1+  DUP  1023 >
-         IF DROP  TRUE
-         ELSE IMOV CURSOR!  @(CURSOR)  BL  =
-              DUP IF IMOV THEN
-         THEN
-      UNTIL
-      BEGIN CURSOR@  1+  DUP  1023 >
-         IF DROP  TRUE
-         ELSE CURSOR!  @(CURSOR)  BL  >
-         THEN
-      UNTIL .CURSOR  ;
-
-Screen 72 not modified
-\ CURSOR-LEFTWORD                              20:32JWB11/11/85
-\ Move cursor left one word.
-: CURSOR-LEFTWORD ( --  -- )
-      @(CURSOR)  BL  >
-      IF -1 CURSOR +!   CURSOR-CHK
-      THEN @(CURSOR)  BL  =
-      IF BEGIN  CURSOR@  1-  DUP  0<
-            IF   DROP  TRUE
-            ELSE CURSOR!  @(CURSOR)  BL  <>
-            THEN
-         UNTIL
-      THEN
-      BEGIN -1 CURSOR +!
-         CURSOR@ 0<
-         @(CURSOR)  BL  =  OR
-      UNTIL FORWARD ;
-Screen 73 not modified
-\ FIND-CHARACTER INSERT-WORDRIGHT              20:34JWB11/11/85
-\ Move cursor to first occurance of inputed character.
-: FIND-CHARACTER ( --  -- )
-         KEY 1 CURSOR +!
-         0 SCREEN  1023 +
-         0 SCREEN CURSOR@ +
-         SCAN+=  +.CURSOR ;
-
-\ Insert word from the insert buffer.
-: INSERT-WORDRIGHT ( -- -- )
-      IPTR @ 0<> IBUF 1- C@ BL = AND
-IF   BEGIN BLANK-AT-END? IPTR @ 0<> IBUF 1- C@ BL = AND AND
-      WHILE IGET REPEAT
-THEN BEGIN BLANK-AT-END? IPTR @ 0<> IBUF 1- C@ BL <> AND AND
-      WHILE IGET REPEAT  ;
-
-Screen 74 not modified
-\ DELETE-WORDRIGHT                             20:35JWB11/11/85
-\ Delete word to the right of the cursor.
-: DELETE-WORDRIGHT ( --  -- )
-      NOT-EMPTY-LINE?
-      IF @(CURSOR)  BL  >
-         IF BEGIN (DELC)  @(CURSOR)  BL  =
-            UNTIL
-         THEN NOT-EMPTY-LINE?
-         IF BEGIN (DELC)  @(CURSOR)  BL <>
-            UNTIL
-         THEN .LINE-TO-END  .CURSOR
-      THEN ;
-
-
-
-
-Screen 75 not modified
-\ PULL-NEXT-LINE                               20:39JWB11/11/85
-\ Pull line next line ( below cursor ) over to the right
-\ of the screen.  Used in  JOIN-LINE.
-: PULL-NEXT-LINE ( --  -- )
-      ?LINE  1+ C/L *
-      DUP  SCREEN  C@  32 =
-      IF   CURSOR@  >R  CURSOR!
-           .CURSOR  DELETE-WORDRIGHT
-           R>  CURSOR!  .CURSOR
-      ELSE DROP
-      THEN ;
-
-
-
-
-
-Screen 76 not modified
-\ MOVE-UPTO-BLANK                              20:40JWB11/11/85
-\
-
-: MOVE-UPTO-BLANK ( adr1 adr2 n   n' )
-      BEGIN DUP  1-  3  PICK  +
-      C@  32 <>  OVER  0<>  AND
-      WHILE 1-
-      REPEAT DUP  DUP  >R
-      IF CMOVE
-      ELSE DROP  2DROP
-      THEN R>  ;
-
-
-
-
-
-Screen 77 not modified
-\ JOIN-LINE                                    20:41JWB11/11/85
-\ Join line under cursor to the one containing the cursor.
-: JOIN-LINE ( --  -- )
-      ?LINE  15 -
-      IF ?LINE64*  SCREEN C/L -TRAILING  DUP  63 <
-         IF PULL-NEXT-LINE  1+  DUP  >R  +  ?LINE  1+
-         C/L *  SCREEN  SWAP C/L R>  -  MOVE-UPTO-BLANK
-          ?LINE  1+ C/L *  SCREEN  SWAP  BLANK  ?LINE  .LINE
-          PULL-NEXT-LINE  ?LINE  1+ C/L *  SCREEN C/L
-          -TRAILING  SWAP  DROP  0=
-            IF CURSOR@  >R C/L CURSOR  +!  DELETE-LINE  R>
-             CURSOR!  .CURSOR
-            ELSE .SCREEN-TO-END
-            THEN
-         ELSE 2DROP
-       THEN  THEN ;
-Screen 78 not modified
-\ END-OF-SCREEN  START-OF-SCREEN               21:11JWB11/08/85
-
-\ Move to end of screen.
-: END-OF-SCREEN  ( --  -- )
-      0 SCREEN  1023 -TRAILING
-      NIP CURSOR! .CURSOR ;
-
-\ Move to start of screen.
-: START-OF-SCREEN  ( --  -- )
-         CURSOR OFF .CURSOR ;
-
-
-
-
-
-
-Screen 79 not modified
-\ END-OF-LINE  START-OF-LINE                   20:42JWB11/11/85
-
-\ Move to end of the line.
-: END-OF-LINE ( --  -- )
-         ?LINE64* DUP SCREEN C/L -TRAILING
-         NIP + CURSOR! .CURSOR ;
-
-\ Move to the start of the line.
-: START-OF-LINE ( --  -- )
-         ?LINE64* CURSOR! .CURSOR ;
-
-
-
-
-
-
-Screen 80 not modified
-\ STRING-INPUT                                 21:14JWB11/08/85
-
-\ Fetch string from user and return character count.
-: STRING-INPUT  ( --  n )
-      HERE  1+  30 EXPECT
-      SPAN @ DUP  HERE C!      ;
-
-
-
-
-
-
-
-
-
-
-Screen 81 not modified
-\          .SCH-TARGET                         20:45JWB11/06/85
-
-
-
-
-: .SCH-TARGET
-       1 CLEAR-PROMPT  ." Find string: " ASCII " VEMIT
-       0 SEARCHBUF          COUNT  VTYPE  ASCII " VEMIT
-       0 REPLACEBUF  C@
-       IF   4 SPACES  ." Replace with: " ASCII " VEMIT
-            0 REPLACEBUF    COUNT  VTYPE  ASCII " VEMIT
-       ELSE 4 SPACES  ." (Press any key to cancel.)"
-       THEN ;
-
-
-
-Screen 82 not modified
-\ .SCH-NO-FIND .SCH-ILLEGAL                    20:46JWB11/06/85
-
-
-: .SCH-NO-FIND  ( --  -- )
-          1 CLEAR-PROMPT ." Can't find: " ASCII " VEMIT
-          0 SEARCHBUF  COUNT  VTYPE  ASCII " VEMIT  BEEP
-          PUSH-TO-PROCEED  ;
-
-: .SCH-ILLEGAL ( --  -- )
-        1 CLEAR-PROMPT  ." No FIND argument" BEEP
-        PUSH-TO-PROCEED  ;
-
-
-
-
-
-Screen 83 not modified
-\ .SCH-ABORTED SEARCH-INPUT                    21:16JWB11/08/85
-
-
-: .SCH-ABORTED  ( --  -- )
-          1 CLEAR-PROMPT  ." Search aborted" BEEP
-          PUSH-TO-PROCEED  ;
-
-: SEARCH-INPUT ( --  -- )
-        1 CLEAR-PROMPT
-        ." String to find <return> : "
-        STRING-INPUT ?DUP
-        IF DUP  >R  0  SEARCHBUF  C!
-           HERE  1+  1  SEARCHBUF
-           R>  CMOVE
-        THEN ;
-
-Screen 84 not modified
-\ REPLACE-INPUT                                09:40JWB06/22/85
-
-
-: REPLACE-INPUT
-          1 CLEAR-PROMPT  ." Replace with <return> : "
-          STRING-INPUT  ?DUP
-          IF DUP  >R  0  REPLACEBUF  C!
-             HERE  1+  1  REPLACEBUF R>  CMOVE
-          THEN ;
-
-
-
-
-
-
-
-Screen 85 not modified
-\ .REP-ILLEGAL .REP-MISSING                    20:44JWB11/11/85
-\ Display replace error message.
-: .REP-ILLEGAL ( --  -- )
-    1 CLEAR-PROMPT   ." REPLACE argument too long"
-    BEEP   ;
-
-\ Display replace error message.
-: .REP-MISSING ( --  -- )
-    1 CLEAR-PROMPT
-    ." Missing FIND or REPLACE argument" BEEP   ;
-
-
-
-
-
-
-Screen 86 not modified
-\ REPLACE-VALIDATE                             20:45JWB11/11/85
-
-\ Validate search and replace arguments.
-: REPLACE-VALIDATE ( --  -- )
-    0  SEARCHBUF  C@  0=  0  REPLACEBUF  C@
-    0=  OR
-      IF .REP-MISSING  0
-      ELSE 0  SEARCHBUF  C@  0  REPLACEBUF  C@  <
-         IF .REP-ILLEGAL  0
-         ELSE 1
-         THEN
-      THEN ;
-
-
-
-
-Screen 87 not modified
-\ SEARCH-SCREEN SEARCH-ADJUST                  20:47JWB11/11/85
-
-
-\ Search screen n.
-: SEARCH-SCREEN  (           )
-    BLOCK  OVER  +  OVER  1024 SWAP  -  1
-    SEARCHBUF  0  SEARCHBUF  C@  MATCH  ROT  +  SWAP
-      IF 1
-      ELSE DROP  0
-      THEN ;
-
-
-: SEARCH-ADJUST   0  SEARCHBUF  C@  -  ;
-
-
-
-Screen 88 not modified
-\ SEARCH-TO-END                                23:38JWB06/23/85
-
-: SEARCH-TO-END
-      !(SCREEN#)  FLUSH  .READING  SCREEN#  @
-      BEGIN CUR@ .CLOCK CUR! (KEY?)
-         IF DROP  .SCH-ABORTED  0  $REPLACE  !
-          CURSOR-LEFTWORD  KEY  DROP  EXIT
-         THEN 1+  DUP  ?SCREENS >
-         IF DROP  EMPTY-BUFFERS  .SCH-NO-FIND  0  $REPLACE  !
-          CURSOR-LEFTWORD  EXIT
-         ELSE 0  OVER  SEARCH-SCREEN
-            IF SEARCH-ADJUST  CURSOR!  SCREEN#  !
-             @(SCREEN#)  .SCREEN  .CLEAN EXIT
-            THEN
-         THEN
-    AGAIN ;
-Screen 89 not modified
-\ SEARCH-FILE                                  23:07JWB06/20/85
-
-
-: SEARCH-FILE ( --  -- )
-          -1  $REPLACE  !
-          CURSOR-RIGHTWORD  CURSOR@
-          SCREEN#  @  SEARCH-SCREEN
-          IF   SEARCH-ADJUST  CURSOR!
-          ELSE SEARCH-TO-END
-          THEN ;
-
-
-
-
-
-
-Screen 90 not modified
-\ REPLACE-STRING                               10:51JWB11/10/85
-
-: REPLACE-STRING ( --  -- )
-      $REPLACE  @
-      IF  ADCUR            0
-          SEARCHBUF  C@  BLANK  0
-          REPLACEBUF  COUNT
-          ADCUR            SWAP  CMOVE
-          .CURSOR  ADCUR
-          0  SEARCHBUF  C@  VTYPE
-      THEN ;
-
-
-
-
-
-Screen 91 not modified
-\ HLP1                                         10:48JWB11/10/85
-
-
-: HLP1 ( --  -- )
-      2 20 AT 24 VEMIT ."  or ^E cursor up"
-      2 21 AT 25 VEMIT ."  or ^X cursor down"
-      2 22 AT 26 VEMIT ."  or ^D cursor right"
-      2 23 AT 27 VEMIT ."  or ^S cursor left"
-     26 20 AT ." aD transpose right"
-     26 21 AT ." aS transpose left"
-     26 22 AT 17 VEMIT 217 VEMIT ."   new line"
-     26 23 AT ." F1 more help"
-     52 20 AT ." ^Home  start of text"
-     52 21 AT ."  Home  start of line"
-     52 22 AT ."  End   end of line"
-     52 23 AT ." ^End   end of text"    ;
-Screen 92 not modified
-\ HLP2                                         13:44JWB11/10/85
-
-: HLP2  ( --  --  )
-    2 20 AT  26 VEMIT  221 VEMIT ."  or ^I tab right"
-    2 21 AT 222 VEMIT   27 VEMIT ."  or ^O tab left"
-    2 22 AT  94 VEMIT   26 VEMIT ."  or ^F word right"
-    2 23 AT  94 VEMIT   27 VEMIT ."  or ^A word left"
-   26 20 AT ." ^Q followed by any"
-   29 21 AT    ." character will"
-   29 22 AT    ." move to its"
-   29 23 AT    ." first occurance"
-   52 20 AT ." F7 find string"
-   52 21 AT ." ^L find again"
-   52 22 AT ." F8 find & replace"
-   52 23 AT ." F1 more help" ;
-
-Screen 93 not modified
-\ HLP3                                         17:56JWB11/09/85
-
-: HLP3   ( --  -- )
-     1 20 AT ." ^G  delete char "
-     1 21 AT  17 VEMIT  196 VEMIT ."   backsp & erase"
-     1 22 AT ." DEL backsp & delete"
-     1 23 AT ." ^C see ins buf"
-    22 20 AT ." ^T delete word"    22 21 AT ." ^R recall word"
-    22 22 AT ." ^B clr ins buf"    22 23 AT ." ^V recall char"
-    41 20 AT ." ^Y delete line"    41 21 AT ." ^U erase line"
-    41 22 AT ." aU  erase to EOL"  41 23 AT ." INS insert toggle"
-    61 20 AT ." ^N  insert line"   61 21 AT ." aN split line"
-    61 22 AT ." ^W insert space"   61 23 AT ." F1 more help"  ;
-
-
-
-Screen 94 not modified
-\ HLP4                                         10:48JWB11/10/85
-
-: HLP4   ( --  -- )
-     1 20 AT ."  PgUp previous screen"
-     1 21 AT ." ^R    recall word"
-     1 22 AT ." ^PgUp first screen"
-    26 20 AT ."  PgDn next screen"
-    26 21 AT ." ^C    see ins buf"
-    26 22 AT ." ^PgDn last screen"
-    52 20 AT ." ^Z enter new screen"
-    52 21 AT ." aA shadow  screen"
-    52 22 AT ." F1 more help"  ;
-
-
-
-
-Screen 95 not modified
-\ HLP5                                         17:56JWB11/09/85
-
-: HLP5   ( --  -- )
-     1 20 AT ." ^J = join lines"
-     1 21 AT ." ^P = print screen"
-     1 22 AT ." aB = Better colors?"
-    21 20 AT ." aC = copy 1 screen"
-    21 21 AT ." aD = +transpose"
-    21 22 AT ." aG = get directory"
-    41 20 AT ." aI = screen index"
-    41 21 AT ." aM = copy many scrs"
-    41 22 AT ." aO = open new file"
-    61 20 AT ." aS = -transpose"
-    61 21 AT ." aT = set tab stops"
-    61 22 AT ." ESC= exit editor"
-    61 23 AT ." F1 = more help"    ;
-Screen 96 not modified
-\ HLP6                                         10:04JWB11/10/85
-: HLP6   ( --  -- )
-     1 20 AT ." aF2 set stamp"
-     1 21 AT ." F2  date stamp"
-     1 22 AT ." F3  push line"
-    18 20 AT ." F4 push & Delete"
-    18 21 AT ." F5 pop line"
-    18 22 AT ." F6 spread & pop"
-    38 20 AT ." F7 find string"
-    38 21 AT ." F8 find&replace"
-    38 22 AT ." F9 erase screen"
-    58 20 AT ." aF9 erase to EOS"
-    58 21 AT ." F10 restore screen"
-    58 22 AT ." F1  more help"  ;
-
-
-Screen 97 not modified
-\ HLP0                                         10:41JWB11/10/85
-: HLP0   ( --  -- )
-    1 20 AT ." ^A word left"        1 21 AT ." ^C see ins buf"
-    1 22 AT ." ^D cursor right"     1 23 AT ." ^E cursor up"
-    1 24 AT ." ^F word right"      21 20 AT ." ^G delete under"
-   21 21 AT ." ^H delete behind"   21 22 AT ." ^I tab forward"
-   21 23 AT ." ^J join lines"      21 24 AT ." ^L repeat find"
-   41 20 AT ." ^N ins new line"    41 21 AT ." ^O tab backward"
-   41 22 AT ." ^P print screen"    41 23 AT ." ^Q quick to char"
-   41 24 AT ." ^S cursor right"    61 20 AT ." ^T delete word"
-   61 21 AT ." ^U blank line"
-   61 22 AT ." ^W ins blank char"
-   61 23 AT ." ^Y delete line"
-   61 24 AT ." ^Z new screen"    ;
-
-
-Screen 98 not modified
-\ +HELP .MENU                                  10:48JWB11/10/85
-   VARIABLE  VHELP
-
-: +HELP  ( -- -- )  \ Increment to next help screen.
-    VHELP @ 1+ 7 MOD  VHELP ! ;
-
-: .MENU  ( --  -- )
-    .CLEAN  5  CLEAR-PROMPT
-    CASE  VHELP @    DUP IF .HOLD THEN
-    0 OF  HLP0 ENDOF     1 OF  HLP1  ENDOF
-    2 OF  HLP2  ENDOF    3 OF  HLP3  ENDOF
-    4 OF  HLP4  ENDOF    5 OF  HLP5  ENDOF
-    6 OF  HLP6  ENDOF
-    ENDCASE .CURSOR  ;
-
-
-Screen 99 not modified
-\                                              10:03JWB11/10/85
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-Screen 100 not modified
-\ CERROR                                       14:09JWB11/10/85
-\ Screen color if we have an error.
-    79 CONSTANT CERROR
-    31 CONSTANT CNORMAL
-    14 CONSTANT CBROWSE
-       VARIABLE ERRORS
-
-
-
-
-
-
-
-
-
-
-Screen 101 not modified
-\ COLOR-INPUT                                  20:56JWB11/11/85
-
-
-\ Choose the text background and forground colors.
-: COLOR-INPUT ( --  -- )
-         15 ATRIB !
-         CLEARSCREEN 0 2 AT
-         128 0 DO I ATRIB ! I 4 .R LOOP
-           15 ATRIB !  CR CR
-         ." Choose text color  : "      #IN
-         1 MAX 127 MIN  ATRIB !
-         CLEARSCREEN BORDER .SCREEN .MENU .HOLD .CURSOR ;
-
-
-
-
-Screen 102 not modified
-\ SET-STAMP  SHOW-IBUF                         20:51JWB11/11/85
-\ Reset initials for auto date stamp.
-: SET-STAMP  ( --  -- )
-     $AUTO DUP @ IF OFF ELSE ON THEN
-     $AUTO @
-     IF $INITIALS  C@  0=
-        IF 1 CLEAR-PROMPT ." Enter your initials: "
-            HERE  20 EXPECT  SPAN  @  3  MIN  $INITIALS
-            C!  HERE  $INITIALS  1+  SPAN  @  3  MIN
-            CMOVE   1 CLEAR-PROMPT
-        THEN
-     THEN  .STAMP  .MENU .CURSOR ;
-\ Display contents of insert buffer.
-: SHOW-IBUF ( --  -- )
-      4 CLEAR-PROMPT  0 INSBUF IPTR @ VTYPE
-      CR PUSH-TO-PROCEED .MENU .CURSOR ;
-Screen 103 not modified
-\ ONE-COPY COPY-ABORT                          10:49JWB11/10/85
-     VARIABLE <INCR> VARIABLE FINI?
-\ Copy one screen to another.
-: ONE-COPY  ( --  -- )
-         !(SCREEN#) .CLEAN 2 CLEAR-PROMPT
-          ." Enter screen # to copy from : " #IN  SCREEN#  !
-          @(SCREEN#)  6 21  AT
-          ." Enter screen # to copy to :   " #IN  SCREEN#  !
-         !(SCREEN#) 2 CLEAR-PROMPT  NEW-SCREEN
-         .MENU .HOLD .CURSOR ;
-
-\ Send copy abort message.
-: .CPY-ABORT ( --  -- )
-          6 21 AT
-         ." MULTIPLE BLOCK COPY ABORTED!!" BEEP ;
-
-Screen 104 not modified
-\ (TRANSFER)                                   20:59JWB11/11/85
-\ Copy screem range, first thru last to destination.
-: (TRANSFER) ( first last dest  -- )
-      2  PICK  -  DUP  0<
-      IF    1 <INCR> !  SWAP  1+  ROT
-      ELSE -1 <INCR> !  ROT ROT THEN
-      ?DO  I  DUP  .READING
-           3 CLEAR-PROMPT ." Coppying screen # " .
-           SCREEN#  !  CUR@  NEW-SCREEN   .CLOCK CUR!
-           I OVER  +  DUP  ." to screen # " . .WRITING
-           6 21 AT     ." Press any key to abort copying!"
-           BLOCK  0  SCREEN  SWAP  1024 CMOVE
-           (KEY?) IF .CPY-ABORT LEAVE THEN
-           UPDATE  FLUSH <INCR>  @ +LOOP DROP  ;
-
-
-Screen 105 not modified
-\ MULTI-COPY                                   20:52JWB11/11/85
-: MULTI-COPY
-         !(SCREEN#) .CLEAN 3 CLEAR-PROMPT
-      ." First source screen # :      " #IN  6 21  AT
-      ." Last source screen # :       " #IN  6 22  AT
-      ." First destination screen # : " #IN  (TRANSFER)
-      3 CLEAR-PROMPT NEW-SCREEN   .MENU .HOLD .CURSOR ;
-\ Convert word to upper case.
-: UCASE   HERE  SWAP  OVER  +  SWAP
-      ?DO I  C@  97 122 WITHIN
-         IF 32 I CTOGGLE THEN LOOP ;
-\ Get screen filen name from user.
-: FILENAME-INPUT ( --  adr )
-      BEGIN 1 CLEAR-PROMPT  ." Enter screen file name :   "
-       STRING-INPUT  ?DUP
-      UNTIL UCASE  HERE  ;
-Screen 106 not modified
-\ DRIVE-INPUT                                  20:53JWB11/11/85
-
-: DRIVE-INPUT
-      STRING-INPUT  DUP  UCASE
-      IF HERE  1+  C@  DUP  96 >
-         IF 32 -
-         THEN 64 -  1  MAX  63 MIN
-      ELSE 0 25  BDOS   1+  8 VEMIT  DUP
-       64 +  VEMIT
-      THEN ;
-
-
-
-
-
-
-Screen 107 not modified
-\ QUICK INDEX                                  18:51jwb11/05/85
-: QUICK-INDEX
-      !(SCREEN#) .CLEAN  2 CLEAR-PROMPT
-      ." Enter first screen #  : " #IN CHECK-SCREEN 6 21 AT
-      ." Enter final screen #  : " #IN CHECK-SCREEN 2DUP <
-    IF  SAVE-BUFFERS  CLEARSCREEN    15 1 AT
-       ." Index for screen file  "  FILE? CR CR  1+ SWAP
-     DO  I 3 .R SPACE I BLOCK 2+ 14 VTYPE
-         #OUT @ 60 >
-         IF    CR
-         ELSE #OUT @ 20 MOD 20 SWAP - SPACES  THEN
-         (KEY?) IF KEY 13 = ?LEAVE CR PUSH-TO-PROCEED CR THEN
-     LOOP  CR   PUSH-TO-PROCEED  SSS   5 MOD 5 * $SECONDS !
-     BORDER .STATE .MENU .HOLD NEW-SCREEN
-    ELSE 2DROP THEN ;
-
-Screen 108 not modified
-\ $DIR                                         13:59JWB11/10/85
-\ Default drive input string.
-: $DIR ( --  adr n )
-        " C:*.*" ;
-
-: OPEN-NEW-FILE ( --  -- )
-            !(SCREEN#)
-            FILE @  PREV-FILE  42 CMOVE  FLUSH
-            FILE @ [ DOS ]  CLOSE [ EDITOR ]
-            FILENAME-INPUT  OPEN-SCR
-            IF 1 CLEAR-PROMPT
-               ." Can't find: " FILE? PREV-FILE CUR-FILE
-            42 CMOVE [ DOS ] OPEN-FILE [ EDITOR ]
-            ELSE  SCREEN# OFF
-            THEN  NEW-SCREEN   ;
-
-Screen 109 not modified
-\  QUICK-DIR  ANOTHER-SEARCH                   21:00JWB11/11/85
-\ Lists files on specified drive.
-: QUICK-DIR  ( --  -- )
-         !(SCREEN#) 1 CLEAR-PROMPT CURSOR@
-         ." Enter drive:file - " STRING-INPUT  DROP
-         .BLANK-SCREEN
-         HERE (DIR) .CLEAN
-         1 CLEAR-PROMPT PUSH-TO-PROCEED .MENU
-         NEW-SCREEN CURSOR! .CURSOR  ;
-\ Repeat previous search and replace.
-:  ANOTHER-SEARCH  ( --  -- )
-           !(SCREEN#)  0  0 REPLACEBUF  C!  0 SEARCHBUF  C@
-           IF .SCH-TARGET  SEARCH-FILE
-           ELSE .SCH-ILLEGAL
-           THEN  .CLEAN  .MENU .CURSOR   ;
-
-Screen 110 not modified
-\ BACK-SPACE-KEY  RETURN-KEY  TABSET           21:01JWB11/11/85
-: BACK-SPACE-KEY ( --  -- )
-           KBF 128 AND ( check for insert mode )
-           IF   DELETE-CHARLFT
-           ELSE BACKSPACE  @   THEN   ;
-\ Move to next line.
-: RETURN-KEY ( --  -- )
-       ?LINE 1+ 16 MOD C/L *  DUP SCREEN C/L -TRAILING
-        NIP + CURSOR!  CURSOR-CHK  .CURSOR   ;
-\ Reset the current tab stops.
-: TABSET  ( --  -- )
-         1 CLEAR-PROMPT ." Tab stops are now set at "
-         TAB# @ .  ." enter new setting : "  #IN
-         2 MAX 63 MIN TAB# ! .MENU  .CURSOR ;
-
-
-Screen 111 not modified
-\  ENTER-SCR                                   17:58JWB06/22/85
-: ENTER-SCR ( --  -- )
-      1 CLEAR-PROMPT ASK-SCR GO-SCR
-      .MENU .CURSOR ;
-: FIND-IT ( --  -- )
-          !(SCREEN#)  0  0  REPLACEBUF  C!
-           .CLEAN SEARCH-INPUT  0  SEARCHBUF  C@
-           IF .SCH-TARGET  SEARCH-FILE
-           ELSE .SCH-ILLEGAL
-           THEN .CLEAN .MENU  .CURSOR  ;
-: SEARCH-FOR-IT ( --  -- )
-           !(SCREEN#)  .CLEAN SEARCH-INPUT
-           REPLACE-INPUT  REPLACE-VALIDATE
-           IF .SCH-TARGET  SEARCH-FILE  REPLACE-STRING
-           THEN .CLEAN .MENU .CURSOR  ;
-
-Screen 112 not modified
-\ (IBM)                                        21:50JWB11/07/85
-: (IBM)
-   DUP
-   CASE
-   BACK-TAB    OF TAB-LEFT          ENDOF
-  ^HOME        OF START-OF-SCREEN   ENDOF
-  ^END         OF END-OF-SCREEN     ENDOF
-   HOME        OF START-OF-LINE     ENDOF
-   END         OF END-OF-LINE       ENDOF
-  ^PG-UP       OF FIRST-SCR         ENDOF
-  ^PG-DN       OF LAST-SCR          ENDOF
-   PG-UP       OF PREV-SCREEN       ENDOF
-   LEFT-ARROW  OF BACKUP            ENDOF
-  ^LEFT-ARROW  OF CURSOR-LEFTWORD   ENDOF
-  ^RIGHT-ARROW OF CURSOR-RIGHTWORD  ENDOF
-
-Screen 113 not modified
-\ (IBM) ...                                    21:51JWB11/07/85
-   RIGHT-ARROW OF FORWARD           ENDOF
-    UP-ARROW   OF TAB-UP            ENDOF
-    DOWN-ARROW OF TAB-DOWN          ENDOF
-    PG-DN      OF NEXT-SCREEN       ENDOF
-    INS        OF .STATE            ENDOF
-    ALTA       OF GO-SHADOW         ENDOF
-    ALTB       OF COLOR-INPUT       ENDOF
-    ALTG       OF QUICK-DIR         ENDOF
-    ALTT       OF TABSET            ENDOF
-    ALTO       OF OPEN-NEW-FILE     ENDOF
-    ALTI       OF QUICK-INDEX       ENDOF
-    F1         OF +HELP .MENU       ENDOF
-    ALTF2      OF SET-STAMP         ENDOF
-    F7         OF FIND-IT           ENDOF
-    ENDCASE
-Screen 114 not modified
-\ (IBM) ...                                    18:27JWB11/09/85
-    BROWSING @ IF DROP ELSE
-    CASE
-
-    DEL        OF DELETE-CHAR   ENDOF
-    ALTC       OF ONE-COPY      ENDOF
-    ALTD       OF +TRANSPOSE    ENDOF
-    ALTM       OF MULTI-COPY    ENDOF
-    ALTN       OF SPLIT-LINE    ENDOF
-    ALTU       OF ERASE-EOL     ENDOF
-    ALTS       OF -TRANSPOSE    ENDOF
-
-
-
-
-
-Screen 115 not modified
-\ (IBM) ..                                     22:04JWB06/20/85
-    F2 OF DATE-SCREEN 0 .LINE
-            2 CURSOR! .CURSOR        ENDOF
-    F3 OF PUSH-LINE  TAB-DOWN          ENDOF
-    F4 OF PUSH-LINE  DELETE-LINE       ENDOF
-    F5 OF HOLD-DEPTH  @
-          IF POP-LINE  TAB-UP THEN     ENDOF
-    F6 OF HOLD-DEPTH  @
-          IF SPREAD-LINE POP-LINE THEN ENDOF
-       F8  OF  SEARCH-FOR-IT ENDOF
-       F9  OF  ERASE-SCREEN  ENDOF
-    ALTF9  OF  ERASE-TO-END  ENDOF
-      F10  OF  0  BACKBUF  0
-               SCREEN  1024 CMOVE    CURSOR OFF .SCREEN  ENDOF
-    ENDCASE  THEN  ;
-
-Screen 116 not modified
-
-:  CONTROL-CHAR
-     DUP
-     CASE
-     1 OF CURSOR-LEFTWORD   ENDOF
-     2 OF  IBLANK           ENDOF
-     3 OF  SHOW-IBUF        ENDOF
-     5 OF  TAB-UP           ENDOF
-     4 OF  FORWARD          ENDOF
-     6 OF  CURSOR-RIGHTWORD ENDOF
-     9 OF  TAB-RIGHT        ENDOF
-    12 OF  ANOTHER-SEARCH   ENDOF
-    13 OF  RETURN-KEY       ENDOF
-    15 OF  TAB-LEFT         ENDOF
-
-
-Screen 117 not modified
-\ (EDIT)                                       11:39JWB11/11/85
-
-    16 OF  CLEARSCREEN 1 1 AT PRINT-SCREEN  CLEARSCREEN
-           BORDER .SCREEN .MENU .HOLD .CURSOR        ENDOF
-    17 OF  FIND-CHARACTER   ENDOF
-    19 OF  BACKUP           ENDOF
-    24 OF  TAB-DOWN         ENDOF
-    26 OF  ENTER-SCR        ENDOF
-  ESC  OF  !(SCREEN#) FINI? ON  ENDOF
-    ENDCASE
-
-
-
-
-
-
-Screen 118 not modified
-\ (EDIT)                                       18:25JWB11/09/85
-     BROWSING @ IF DROP ELSE
-     CASE
-     7 OF  DELETE-CHAR      ENDOF
-    BS OF  BACK-SPACE-KEY   ENDOF
-    10 OF  JOIN-LINE        ENDOF
-    14 OF  SPREAD-LINE      ENDOF
-    18 OF  INSERT-WORDRIGHT ENDOF
-    20 OF  DELETE-WORDRIGHT ENDOF
-    21 OF  ERASE-LINE       ENDOF
-    22 OF  IGET             ENDOF
-    23 OF  SPREAD-CHAR      ENDOF
-    25 OF  DELETE-LINE      ENDOF
-    ENDCASE  THEN ;
-
-
-Screen 119 not modified
-\ (EDIT) ...                                   11:40JWB11/11/85
-: (EDIT)    BORDER  .MENU   .STATE
-         @(SCREEN#) .SCREEN
-      ERRORS @
-      IF ATRIB @ CERROR ATRIB ! .LINE-TO-END
-         CURSOR-LEFTWORD ATRIB ! THEN
-      BEGIN PCKEY  DUP 31 >
-      IF  BROWSING @ NOT
-          IF KBF   128 AND
-             IF    INSERT-CHAR
-             ELSE  PUT-CHAR THEN
-          ELSE  DROP  THEN
-      ELSE  ?DUP
-            IF    CONTROL-CHAR
-            ELSE  (IBM)   THEN
-      THEN FINI? @ UNTIL  ;
-Screen 120 not modified
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-Screen 121 not modified
-\ (VEDIT)                                      23:19JWB11/09/85
-ONLY FORTH ALSO DOS ALSO FORTH DEFINITIONS
-: (VEDIT)  ( scr#   -- )
-         [ EDITOR ] DECIMAL 1 ?ENOUGH   DUP SCR !
-         TIB   DP @ - 4056 U<
-         IF   ." Not enough memory to EDIT"
-         ELSE  DP  @  DUP  $SCRATCH  !
-           3684 +  DP  !
-           HOLD-DEPTH  OFF  0  SEARCHBUF
-           64 ERASE  0  REPLACEBUF  64 ERASE
-           8 TAB# !  FINI? OFF  IBLANK
-           FILE @ CUR-FILE 42 CMOVE FILE @ OLD-FILE !
-           CUR-FILE  !FILES OPEN-FILE  SW  $INIT
-           TSMH OFF $SECONDS OFF  BROWSING @
-           IF  CBROWSE  ELSE  CNORMAL THEN  ATRIB !
-           0 MAX ?SCREENS MIN SCREEN# ! (EDIT)
-Screen 122 not modified
-\ (VEDIT) ..                                   23:19JWB11/09/85
-             15 ATRIB !
-             BORDER .STATE  NEW-SCREEN  0 20 AT
-             SCREEN# @ SCR !
-             FILE @  PREV-FILE  42 CMOVE
-             FLUSH  FILE @  CLOSE   $SCRATCH @ DP !  -SW
-             ." You were editing screen # " SCREEN#  @  .
-             ." of " FILE? CR
-             ." Source file and disk directory updated." CR
-             OLD-FILE  @ !FILES OPEN-FILE
-             ." Current file is : " FILE?   LITTLE-CURSOR
-          THEN  CR  ;  FORTH
-
-
-
-
-Screen 123 not modified
-\ <WHERE>                                      14:10JWB11/10/85
-
-: <WHERE> ( pos scr   -- )
-         CR R> R> R> 2DUP >R >R SPACE TYPE SPACE >R
-         2DUP ." Screen " . ." Line "  C/L / .
-         ORDER  DISK-ERROR @ 0= [ EDITOR ]
-         KEY BL = AND
-         IF SWAP  CURSOR! ERRORS ON (VEDIT) THEN  ;  FORTH
-
-' <WHERE> IS WHERE
-
-
-
-
-
-
-Screen 124 not modified
-\  VEDIT  VED BROWSE                           14:10JWB11/10/85
-
-: BROWSE  ( scr#  -- )
-         [ EDITOR ] BROWSING ON
-         CURSOR OFF ERRORS OFF  (VEDIT) ;  FORTH
-' BROWSE IS EDIT
-: VEDIT  ( scr#  -- )
-         [ EDITOR ] BROWSING OFF
-         CURSOR OFF ERRORS OFF  (VEDIT) ;  FORTH
-: VED  ( --  -- )
-        [ EDITOR ]  BROWSING OFF
-        SCR @ 0 MAX ?SCREENS MIN
-        CURSOR OFF  ERRORS OFF  (VEDIT) ;  FORTH
-
-
-
-Screen 125 not modified
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-Screen 126 not modified
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-
-Screen 127 not modified
-
-ONLY EDITOR ALSO FORTH ALSO
-\ Leave true flag if KBF has changed.  New value in $KBF .
-CODE KBF?  ( --  flag ) \ Was:  $KBF @ KBF DUP $KBF ! <>
-         2 # AH MOV      \ Function number 2 for kb flag
-             22 INT      \ Call KBF is returned in AL
-          AH AH SUB      \ Clear high byte of AX.
-      $KBF # DI MOV      \ Address of old KBF to DI
-     0 [DI]  BX MOV      \ Fetch old value of KBF
-          AX BX CMP      \ Compare new value with old.
-0= IF    AX AX SUB      \ Leave false flag if the same
-  ELSE AX 0 [DI] MOV     \ Update $KBF and
-        -1 # AX MOV      \ return true if KBF has changed.
-  THEN          1PUSH    \ Push AX and fall into NEXT
-                END-CODE
-: TEST CLEARSCREEN BEGIN CR KBF? U. $KBF ? KEY? UNTIL ;
-Screen 128 not modified
-\                                              18:23jwb11/05/85
-ONLY EDITOR ALSO FORTH ALSO DEFINITIONS
-
-CREATE TSMH  4 ALLOT
-CODE  @TIME ( --  -- )
-     44 ( 2C) # AH MOV
-     33 ( 21)      INT
-         TSMH # DI MOV
-        DX  0 [DI] MOV
-        CX  2 [DI] MOV
-             NEXT  END-CODE
-: TT TSMH C@ ; : SS TSMH 1+ C@ ;  : MM TSMH 2+ C@ ;
-: HH TSMH 3 + C@ ;
-: TEST CLEARSCREEN
-        BEGIN 1 1 AT @TIME HH 3 U.R MM 3 U.R
-                           SS 3 U.R TT 3 U.R   KEY? UNTIL ;
-Screen 129 not modified
-\ ?MODE                                        23:09JWB11/04/85
-\ Read current video mode.
-\ 0 = 40x25 bw          3 = 80x25 color  4 = 320x200 color
-\ 1 = 40x25 color       5 = 320x200 bw
-\ 2 = 80x25 bw          6 = 640x200 bw
-\
-CODE ?MODE   ( --  mode )
-         15 # AH MOV             \ Read video state is #15.
-              16 INT             \ Call video io routines.
-           AH AH SUB             \ Clear high byte.
-                 1PUSH           \ Push AX which contains mode.
-                 END-CODE
-\ Note Function 15 of   16 INT  also returns:
-\ Number of columns on the screen in  AH  and current active
-\ page in BH.  Both of these are ignored by ?MODE
-: MODE!  0 0 0 VIDEO-IO 2DROP 2DROP ;
-</code>